group 'com.guo'
version '1.0-SNAPSHOT'

// 所有子项目的通用配置
subprojects {
    apply plugin: 'java'

    version = '1.0'
    /***
     * 编译版本
     */
    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    // java编译的时候缺省状态下会因为中文字符而失败
    [compileJava,compileTestJava,javadoc]*.options*.encoding = 'UTF-8'
    sourceSets {
        main {
            java {
                srcDirs = ['src/main/java']
            }
            resources {
                srcDirs = ['src/main/resources','src/main/java']
            }
        }
    }
    //定义版本号
    ext {
        iceVersion = '3.7.0'
    }
    //将src文件夹中的资源文件同时打包

    repositories {
        maven{ url 'http://maven.aliyun.com/nexus/content/groups/public/'}
        mavenCentral()
    }

    jar {
        manifest {
            attributes("Implementation-Title": "Gradle")
        }
    }

    configurations {
        // 所有需要忽略的包定义在此
        // all*.exclude group: 'commons-httpclient'
        //all*.exclude group: 'commons-logging'
        //all*.exclude group: 'commons-beanutils', module: 'commons-beanutils'
    }

    dependencies {

        /***
         * ICE
         */
        compile "com.zeroc:ice:$iceVersion"
        compile "com.zeroc:icegrid:${iceVersion}"
        compile "com.zeroc:icestorm:${iceVersion}"
        compile "com.zeroc:icebox:${iceVersion}"

        /***
         * 测试资源
         */
        testCompile group: 'junit', name: 'junit', version: '4.12'


        // 依赖maven中不存在的jar
        ext.jarTree = fileTree(dir: 'libs', include: '**/*.jar')
        ext.rootProjectLibs = new File(rootProject.rootDir, 'libs').getAbsolutePath()
        ext.jarTree += fileTree(dir: rootProjectLibs, include: '**/*.jar')

        compile jarTree


    }
/***
 * 显示当前项目下所有用于 compile 的 jar.资源列表
 */
    task listJars(description: 'Display all compile jars.') << {
        configurations.compile.each { File file -> println file.name }
    }
    /***
     *  清除任务：清除编译目录
     */
    task clearBuild(type:Delete){
        delete 'build','target'
    }
    /***
     *  复制任务：copy依赖jar
     *  复制运行时依赖的jar
     */
    task copyJarDependents(type:Copy){
        from configurations.runtime
        into ('build/libs/lib')
    }
    /***
     *  构建任务：执行打包，copy依赖
     */
    task release(type: Copy,dependsOn: [build,copyJarDependents]) {
        // from 'conf'
        // into ('build/libs/eachend/conf') // 目标位置
    }
}