// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.2'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
        classpath 'com.novoda:bintray-release:0.9.1'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }

    tasks.withType(Javadoc) {
        options {
            encoding "UTF-8"
            charSet 'UTF-8'
            links "http://docs.oracle.com/javase/7/docs/api"
        }
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

def file = 'local.properties'
if (new File(file).exists()) {
    Properties properties = new Properties()
    properties.load(new FileInputStream(file))
    if ('true' == properties['SMART_PUBLISH']) {
        subprojects {
            if (name.startsWith("refresh-")) {
                group = SMART_GROUP
                version = SMART_VERSION
                if (name.split('-').length > 2) {
                    afterEvaluate {
                        publish {
                            userOrg = SMART_USER
                            groupId = group
                            artifactId = name
                            desc = description
                            publishVersion = version
                            website = "https://github.com/scwang90/${rootProject.name}"
                        }
                    }
                    apply plugin: 'com.novoda.bintray-release'
                }

            }
        }
    }
}