# Copyright (C) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
import("//build/ohos.gni")
import("../core_service/telephony_core_service.gni")

TELEPHONY_EXT_WRAPPER_ROOT = "services/telephony_ext_wrapper"
DATA_SERVICE_EXT_WRAPPER_ROOT = "services/data_service_ext_wrapper"

ohos_shared_library("tel_cellular_data") {
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  use_exceptions = true
  branch_protector_ret = "pac_ret"
  sources = [
    "$DATA_SERVICE_EXT_WRAPPER_ROOT/src/data_service_ext_wrapper.cpp",
    "$TELEPHONY_EXT_WRAPPER_ROOT/src/telephony_ext_wrapper.cpp",
    "services/src/apn_manager/apn_holder.cpp",
    "services/src/apn_manager/apn_item.cpp",
    "services/src/apn_manager/apn_manager.cpp",
    "services/src/apn_manager/connection_retry_policy.cpp",
    "services/src/cellular_data_controller.cpp",
    "services/src/cellular_data_dump_helper.cpp",
    "services/src/cellular_data_handler.cpp",
    "services/src/cellular_data_incall_observer.cpp",
    "services/src/cellular_data_rdb_observer.cpp",
    "services/src/cellular_data_roaming_observer.cpp",
    "services/src/cellular_data_service.cpp",
    "services/src/cellular_data_service_stub.cpp",
    "services/src/cellular_data_setting_observer.cpp",
    "services/src/data_connection_manager.cpp",
    "services/src/data_connection_monitor.cpp",
    "services/src/data_switch_settings.cpp",
    "services/src/sim_account_callback_proxy.cpp",
    "services/src/state_machine/activating.cpp",
    "services/src/state_machine/active.cpp",
    "services/src/state_machine/cellular_data_state_machine.cpp",
    "services/src/state_machine/default.cpp",
    "services/src/state_machine/disconnecting.cpp",
    "services/src/state_machine/inactive.cpp",
    "services/src/state_machine/incall_data_state_machine.cpp",
    "services/src/state_notification.cpp",
    "services/src/traffic_management.cpp",
    "services/src/utils/cellular_data_hisysevent.cpp",
    "services/src/utils/cellular_data_net_agent.cpp",
    "services/src/utils/cellular_data_rdb_helper.cpp",
    "services/src/utils/cellular_data_settings_rdb_helper.cpp",
    "services/src/utils/cellular_data_utils.cpp",
    "services/src/utils/net_manager_call_back.cpp",
    "services/src/utils/net_manager_tactics_call_back.cpp",
    "services/src/utils/network_search_callback.cpp",
  ]

  include_dirs = [
    "$TELEPHONY_EXT_WRAPPER_ROOT/include",
    "$DATA_SERVICE_EXT_WRAPPER_ROOT/include",
    "services/include",
    "services/include/common",
    "services/include/state_machine",
    "services/include/utils",
    "services/include/apn_manager",
    "interfaces/innerkits",
  ]

  external_deps = [
    "ability_base:want",
    "ability_base:zuri",
    "ability_runtime:abilitykit_native",
    "ability_runtime:data_ability_helper",
    "ability_runtime:dataobs_manager",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "core_service:libtel_common",
    "core_service:tel_core_service_api",
    "data_share:datashare_common",
    "data_share:datashare_consumer",
    "eventhandler:libeventhandler",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "hitrace:hitrace_meter",
    "init:libbeget_proxy",
    "init:libbegetutil",
    "ipc:ipc_single",
    "netmanager_base:net_conn_manager_if",
    "netmanager_base:net_policy_manager_if",
    "netmanager_base:net_stats_manager_if",
    "relational_store:native_dataability",
    "relational_store:native_rdb",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
    "telephony_data:tel_telephony_data",
  ]

  defines = [
    "TELEPHONY_LOG_TAG = \"CellularData\"",
    "LOG_DOMAIN = 0xD001F03",
  ]

  if (defined(global_parts_info) &&
      defined(global_parts_info.powermgr_power_manager) &&
      global_parts_info.powermgr_power_manager) {
    external_deps += [ "power_manager:powermgr_client" ]
    defines += [ "ABILITY_POWER_SUPPORT" ]
  }

  if (telephony_hicollie_able) {
    external_deps += [ "hicollie:libhicollie" ]
    defines += [ "HICOLLIE_ENABLE" ]
  }

  if (defined(global_parts_info) &&
      defined(global_parts_info.communication_netmanager_enhanced)) {
    defines += [ "OHOS_BUILD_ENABLE_DATA_SERVICE_EXT" ]
  }

  cflags_cc = [
    "-O2",
    "-D_FORTIFY_SOURCE=2",
  ]

  defines += telephony_extra_defines

  part_name = "cellular_data"
  subsystem_name = "telephony"
}