VERSION 10.0
SYNCHRONOUS_ONLY
INCLUDE _std_medium
INCLUDE _ht350
INCLUDE header

HELP hlp1, view("help nwrandom")
RESET res1

SCRIPT PREINIT
BEGIN
		program initialize
END

SCRIPT POSTINIT
BEGIN
		main.ed_new.setvalue "_random"
END

DIALOG main, title("nwrandom - Generate Random Network")
BEGIN
	
	TEXT tx_nodes 50 30 100 ., label("Number of nodes:")
	SPINNER sp_nodes 160 30 50 ., label("Nodes") default(10) max(9999)
	
	TEXT tx_nets 220 30 130 ., label("Number of networks:")
	SPINNER sp_nets 350 30 50 ., label("Networks") default(1) max(999) option(ntimes)
	
	GROUPBOX gb_ties 220 60 160 100, label("Arc/edge")
	RADIO rb_directed 240 90 100 ., label("Directed") first
	RADIO rb_undirected 240 110 120 ., label("Undirected") last option(undirected)
	
	GROUPBOX gb_prob 50 60 160 100, label("Ties/density")
	RADIO rb_prob 70 90 100 ., label("Tie probability") first
	RADIO rb_density 70 110 120 ., label("Network density") last
	EDIT ed_prob 150 130 50 ., label("prob") numonly default("0.01")
	
	INCLUDE nw_newnet_opt
END

LIST netlist
BEGIN
	// intentionally empty
	// this list will be populated by _nwdialog.ado
END

PROGRAM initialize
BEGIN
	put "_nwdialog nwrandom"
	stata hidden immediate
END

PROGRAM command
BEGIN

	put "nwrandom " main.sp_nodes 
	beginoptions
		if main.rb_prob {
			put " prob(" main.ed_prob ")"
		}
		if main.rb_density {
			put " density(" main.ed_prob ")"
		}
		
		optionarg main.sp_nets
		option main.rb_undirected
		option main.cx_xvars
		optionarg main.ed_new
		optionarg main.ed_labs 
		optionarg main.ed_vars
	endoptions
	stata
END
*! v1.5.0 __ 17 Sep 2015 __ 13:09:53
*! v1.5.1 __ 17 Sep 2015 __ 14:54:23