apply plugin: 'maven'
apply plugin: 'maven-publish'

Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())
def REMOTE_MAVEN_RELEASE = properties.getProperty('REMOTE_MAVEN_RELEASE')
def REMOTE_MAVEN_SNAPSHOT = properties.getProperty('REMOTE_MAVEN_SNAPSHOT')
def MAVEN_USERNAME = properties.getProperty('MAVEN_USERNAME')
def MAVEN_PASSWORD = properties.getProperty('MAVEN_PASSWORD')

static def which(components, customArtifact) {
    if (customArtifact.length() > 0) return null
    if (components.findByName('release')) {
        return components.release
    } else {
        return components.java
    }
}

afterEvaluate { project ->
    def customArtifact = rootProject.ext.CUSTOM_ARTIFACT

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from which(components, customArtifact)
                group = rootProject.ext.DEFAULT_GROUP_ID
                artifactId = rootProject.ext.DEFAULT_ARTIFACT_ID
                version = rootProject.ext.DEFAULT_VERSION
                if (customArtifact.length() > 0) {
                    artifact customArtifact
                }

            }
        }
        repositories {
            maven {
                url = rootProject.ext.DEFAULT_VERSION.endsWith('SNAPSHOT') ? REMOTE_MAVEN_SNAPSHOT : REMOTE_MAVEN_RELEASE
                credentials {
                    username MAVEN_USERNAME
                    password MAVEN_PASSWORD
                }
            }
        }
    }
}