import groovy.text.SimpleTemplateEngine

buildscript {
    repositories {
        maven { url("https://maven.aliyun.com/repository/public") }
        maven { url("https://maven.aliyun.com/repository/spring") }
        maven { url("https://maven.aliyun.com/repository/mapr-public") }
        maven { url("https://maven.aliyun.com/repository/spring-plugin") }
        maven { url("https://maven.aliyun.com/repository/gradle-plugin") }
        maven { url("https://maven.aliyun.com/repository/google") }
        maven { url("https://maven.aliyun.com/repository/jcenter") }
    }
}
HashMap<String, String> systemEnv = new HashMap<String, String>(System.getenv())

ext {
    mainVersion = systemEnv.getOrDefault("MAIN_VERSION", "1.0.0")
    mavenRepositoryUrlList = [
            "https://maven.aliyun.com/repository/public",
            "https://maven.aliyun.com/repository/spring",
            "https://maven.aliyun.com/repository/mapr-public",
            "https://maven.aliyun.com/repository/spring-plugin",
            "https://maven.aliyun.com/repository/gradle-plugin",
            "https://maven.aliyun.com/repository/google",
            "https://maven.aliyun.com/repository/jcenter",
    ]
    gitCommitId = { ->
        String gitCommitIdKey = "GIT_COMMIT_ID"
        if (!systemEnv.containsKey(gitCommitIdKey)) {
            String defaultGitCommitId = 'developing'
            println("WARNING: ${gitCommitIdKey} not found in env, using '${defaultGitCommitId}'")
            return defaultGitCommitId
        }
        return systemEnv.get(gitCommitIdKey).trim()
    }
    fullVersion = "${ext.mainVersion}-C${ext.gitCommitId()}"
    renderText = { File templateFile, Map<String, String> dataMap ->
        return doRenderText(templateFile, dataMap)
    }
    renderFile = { File templateFile, Map<String, String> dataMap, File targetFile ->
        doRenderFile(templateFile, dataMap, targetFile)
    }
    dockerRegistry = systemEnv.getOrDefault("DOCKER_REGISTRY", "docker.io")
    chartMuseum = systemEnv.getOrDefault("CHART_MUSEUM", "http://insecure.chart.museum.local")
    namespace = "nebula"
    backendSoftwareName = "nebula-ce-backend"
    frontendSoftwareName = "nebula-ce-frontend"
    graphAnalysisNamespace = "graph-analysis"
    graphAnalysisSoftwareName = "graph-analysis-frontend"
    algoSoftwareName = "nebula-ce-algo"
}

version = project.rootProject.ext.fullVersion

private void doRenderFile(File templateFile, Map<String, String> dataMap, File targetFile) {
    println("templateFile(${templateFile.getAbsolutePath()}) -> targetFile(${targetFile.getAbsolutePath()})")
    project.file(targetFile).parentFile.mkdirs()
    project.file(targetFile).text = doRenderText(templateFile, dataMap)
}

private String doRenderText(File templateFile, Map<String, String> dataMap) {
    println("templateFile(${templateFile.getAbsolutePath()})")
    return new SimpleTemplateEngine()
            .createTemplate(templateFile.text)
            .make(dataMap)
}