plugins {
    id 'java'
    id 'application'
}

group = 'io.github.tzfun.jvmm'
version = '2.1.0'

ext {
    nettyVersion = "4.1.65.Final"
    nettyNativeSslVersion = "2.0.41.Final"
    junitJupiterVersion = "5.7.0"
    slf4jVersion = "1.7.30"
    logbackVersion = "1.4.5"
    gsonVersoion = "2.8.6"
    commonsCli = "1.5.0"
    cfrVersion = "0.152"
    oshiVersion = "6.4.0"
    snakeyamlVersion = "1.29"
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'signing'

    [compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'

    compileJava {
        options.compilerArgs << "-parameters" << "-Xlint:unchecked" << "-Xlint:deprecation"
    }

    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8

    repositories {
        maven { url 'https://s01.oss.sonatype.org/content/repositories/snapshots/' }
        maven { url 'https://maven.aliyun.com/repository/public/' }
        mavenCentral()
    }

    dependencies {
        testImplementation "org.junit.jupiter:junit-jupiter-api:${junitJupiterVersion}"
        testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitJupiterVersion}"
    }

    test {
        useJUnitPlatform()
    }
}

if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }
}