subprojects {
    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'maven'
	apply plugin: 'signing'
	
	group = 'xyz.noark'  
	version = '3.2.0-SNAPSHOT'
	
	sourceCompatibility = 1.8  
	targetCompatibility = 1.8  

	[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

    repositories {
    	maven { url 'http://maven.aliyun.com/nexus/content/groups/public' }
    	mavenCentral()
    	jcenter()
	}

    dependencies {
		testImplementation 'junit:junit:4.12'
    }

    jar {
     	manifest.attributes provider: '小流氓'
		manifest.attributes["Created-By"] = "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})"
		manifest.attributes["Implementation-Title"] = project.name
		manifest.attributes["Implementation-Version"] = project.version
    }
    
    javadoc {
    	options{
    		encoding "UTF-8"
    		charSet 'UTF-8'
    		author true
    		version true
    		links "http://docs.oracle.com/javase/8/docs/api/"
    	}
    }
    
    ext."signing.keyId"='15567893'
	ext."signing.password"=System.getenv('SIGNING_PASSWORD')
	ext."signing.secretKeyRingFile"=System.getenv('SIGNING_SECRETKEYRINGFILE')
	
	signing {
	    //sign configurations.archives
	}
	
	uploadArchives {
	    repositories {
	        mavenDeployer {
	            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
	
	            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
	                authentication(userName: System.getenv('OSSRH_USER'), password: System.getenv('OSSRH_PASSWORD'))
	            }
	
	            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
	                authentication(userName: System.getenv('OSSRH_USER'), password: System.getenv('OSSRH_PASSWORD'))
	            }
	            
	            pom.project {
	        		name 'Noark'
	        		packaging 'jar'
	        		description 'This is a game server framework.'
	        		url 'http://noark.xyz'
	
	        		scm {
	          			connection 'scm:git:git@gitee.com:xiaoe/noark3.git'
	          			developerConnection 'scm:git:git@gitee.com:xiaoe/noark3.git'
	          			url 'https://gitee.com/xiaoe/noark3/'
	        		}
	
	        		licenses {
	          			license {
	            			name 'The Apache License, Version 2.0'
	            			url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
	          			}
	        		}
	
	        		developers {
	          			developer {
	            			id 'xiaoe'
		            		name '小流氓'
		            		email '176543888@qq.com'
		            		url "http://blog.noark.xyz"
	          			}
	        		}
	        	}
	        }
	    }
	}
	
	task sourceJar(type: Jar) {
		from sourceSets.main.allJava
		classifier = 'sources'
	}
	
	task javadocJar(type: Jar) {
	    from javadoc
	    classifier = 'javadoc'
	}
	
	artifacts {
        archives sourceJar
        archives javadocJar
    }
}