buildscript {
    ext {
        springBootVersion = '1.5.10.RELEASE'
    }
    repositories {
        maven {
            name = 'aliyun-nexus'
            url = 'http://maven.aliyun.com/nexus/content/groups/public/'
        }
        jcenter()
        mavenLocal()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

configure(allprojects) { project ->
    apply plugin: 'java'

    group = 'me.kennylee'
    version = '0.0.1-SNAPSHOT'

    sourceCompatibility = 1.8

    repositories {
        maven {
            name = 'aliyun-nexus'
            url = 'http://maven.aliyun.com/nexus/content/groups/public/'
        }
        jcenter()
        mavenLocal()
    }
}

project('sms') {
    description = '手机验证码核心模块.'
    archivesBaseName = "sms-code"
    version = '1.0.0'

    dependencies {
        compile 'org.slf4j:slf4j-api:1.7.9'

        compileOnly('org.projectlombok:lombok:1.16.20')
        compile 'com.aliyun:aliyun-java-sdk-core:3.2.5'
        compile files("$rootProject.projectDir/libs/aliyun-java-sdk-dysmsapi-1.0.0-SANPSHOT.jar")
        compile 'com.google.guava:guava:23.0'
        compile 'org.apache.commons:commons-lang3:3.7'
        compile 'com.google.code.gson:gson:2.8.2'

        // validator depends
        compile 'net.sf.ehcache:ehcache:2.10.4'
        // 如果用到spring cache..
        compile 'org.springframework:spring-context:4.2.3.RELEASE'

        testCompile 'junit:junit:4.12'
    }
}

project('web') {
    description = 'web模块，演示等用途.'

    apply plugin: 'org.springframework.boot'

    dependencies {
        compile('org.springframework.boot:spring-boot-starter-cache')
        compile('org.springframework.boot:spring-boot-starter-thymeleaf')
        compile('org.springframework.boot:spring-boot-starter-web')
        compileOnly('org.projectlombok:lombok')
        testCompile('org.springframework.boot:spring-boot-starter-test')

        compile(project(':sms'))
    }
}