buildscript {
    apply from: 'config.gradle'
    ext.FAST_MIRROR_REPO_URL = 'https://maven.aliyun.com/nexus/content/groups/public/'
    ext.JEESITE_PRIVATE_REPO_URL = 'http://maven.jeesite.net/repository/maven-public'
    repositories {
        maven { url FAST_MIRROR_REPO_URL }
        maven {
            allowInsecureProtocol = true
            url JEESITE_PRIVATE_REPO_URL
        }
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${jarVersion.springboot}")
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven-publish'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'

    group = 'com.jeesite'
    version = '4.5.0'

    sourceCompatibility = 1.8

    [compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << '-Xlint:unchecked' << '-Xlint:deprecation'
        }
    }

    repositories {
        mavenLocal()
        maven { url FAST_MIRROR_REPO_URL }
        maven {
            allowInsecureProtocol = true
            url JEESITE_PRIVATE_REPO_URL
        }
        mavenCentral()
    }

    dependencies {
        compileOnly('com.google.code.findbugs:annotations:3.0.1')
        implementation('org.springframework.boot:spring-boot-starter')
        testImplementation('org.springframework.boot:spring-boot-starter-test')
        testImplementation('org.junit.vintage:junit-vintage-engine') { // for JUnit4 support
            exclude group: 'org.hamcrest', module: 'hamcrest-core'
        }
    }

    jar {
        enabled = true
        bootJar.enabled = false
        archiveClassifier = 'snapshot'
        manifest {
            attributes('Implementation-Title': 'Gradle',
                    'Implementation-Version': archiveVersion)
        }
    }

    test {
        systemProperty 'spring.profiles.active', System.getProperty('spring.profiles.active')
    }

    processResources {
        filesMatching('application.properties') {
            expand(project.properties)
        }
    }

    configurations {
        dbtestImplementation.extendsFrom testImplementation
    }

    sourceSets {
        dbtest {
            java {
                compileClasspath += main.output + test.output
                runtimeClasspath += main.output + test.output
                srcDir file('src/dbtest/java')
            }
            resources.srcDir file('src/dbtest/resources')
        }
    }

    idea {
        module {
            testSourceDirs += file('src/dbtest/java')
        }
    }

    task dbtest(type: Test) {
        testClassesDirs = sourceSets.dbtest.output.classesDirs
        classpath = sourceSets.dbtest.runtimeClasspath
    }

    tasks.withType(Test) {
        reports.html.outputLocation.set(file("${reporting.baseDir}/${name}"))
    }
}

project(':jeesite-common') {
    dependencies {
        compileOnly('org.apache.commons:commons-lang3')
        compileOnly("org.apache.commons:commons-text:${jarVersion.commons_text}")
        compileOnly('commons-codec:commons-codec')
        compileOnly("commons-io:commons-io:${jarVersion.commons_io}")
        compileOnly("commons-beanutils:commons-beanutils:${jarVersion.commons_beanutils}")
        compileOnly("de.ruedigermoeller:fst:${jarVersion.fst}")
        compileOnly('com.fasterxml.jackson.core:jackson-core')
        compileOnly('com.fasterxml.jackson.core:jackson-databind')
        compileOnly('com.fasterxml.jackson.dataformat:jackson-dataformat-xml')
        compileOnly("com.alibaba:fastjson:${jarVersion.fastjson}")
        compileOnly('jaxen:jaxen')
        compileOnly('org.yaml:snakeyaml')
        compileOnly('org.apache.httpcomponents:httpclient')
        compileOnly("org.apache.commons:commons-email:${jarVersion.commons_email}")
        compileOnly("eu.bitwalker:UserAgentUtils:${jarVersion.UserAgentUtils}")
        compileOnly("net.coobird:thumbnailator:${jarVersion.thumbnailator}")
        compileOnly("com.twelvemonkeys.imageio:imageio-jpeg:${jarVersion.twelvemonkeys}")
        compileOnly("com.bladejava:blade-patchca:${jarVersion.blade_patchca}")
        compileOnly("net.sf.jmimemagic:jmimemagic:${jarVersion.jmimemagic}") {
            exclude group: 'xerces', module: 'xercesImpl'
            exclude group: 'org.codehaus.jackson', module: 'jackson-xc'
            exclude group: 'org.codehaus.jackson', module: 'jackson-jaxrs'
            exclude group: 'log4j', module: 'log4j'
        }
        compileOnly("com.google.zxing:core:${jarVersion.zxing}")
        compileOnly("com.google.zxing:javase:${jarVersion.zxing}")
        compileOnly("org.apache.poi:poi:${jarVersion.poi}") {
            exclude group: 'commons-codec', module: 'commons-codec'
        }
        compileOnly("org.apache.poi:poi-ooxml:${jarVersion.poi}")
        compileOnly("org.apache.poi:poi-ooxml-schemas:${jarVersion.poi}")
        compileOnly("org.apache.poi:poi-scratchpad:${jarVersion.poi}")
        compileOnly("com.belerweb:pinyin4j:${jarVersion.pinyin4j}")
        compileOnly('org.slf4j:slf4j-api')
        compileOnly('org.slf4j:jcl-over-slf4j')
        compileOnly('org.slf4j:jul-to-slf4j')
        compileOnly('org.slf4j:log4j-over-slf4j')
        compileOnly('ch.qos.logback:logback-classic')
        compileOnly('org.springframework:spring-beans')
        compileOnly('org.springframework:spring-web')
        compileOnly('org.springframework.boot:spring-boot')
        compileOnly('junit:junit')
        compileOnly('javax.servlet:javax.servlet-api')
    }
}

project(':jeesite-module-core') {
    dependencies {
        implementation("com.jeesite:jeesite-framework:${jarVersion.jeesite}")
        testImplementation("org.postgresql:postgresql:${jarVersion.postgresql}")
        testImplementation("mysql:mysql-connector-java:${jarVersion.mysql}")
    }

    test {
        exclude 'com/jeesite/test/**'
    }

    task copyInitDataToResDir(type: Copy) {
        into 'src/main/resources/com/jeesite/modules/sys/db'
        from('src/main/java/com/jeesite/modules/sys/db') {
            include '*.xlsx'
        }
    }
    processResources.dependsOn copyInitDataToResDir
}

project(':jeesite-module-cms') {
    dependencies {
        implementation project(':jeesite-module-core')
        implementation("com.jeesite:jeesite-framework:${jarVersion.jeesite}")
    }

    task copyInitDataToResDir(type: Copy) {
        into '/src/main/resources/com/jeesite/modules/cms/db'
        from('/src/main/java/com/jeesite/modules/cms/db') {
            include '*.xlsx'
        }
    }
    processResources.dependsOn copyInitDataToResDir
}