plugins {
    id 'java'
    id "com.google.protobuf" version "0.8.6"
}

group 'com.softwin.crypto_currency'
version '1.0-SNAPSHOT'
compileJava.options.encoding = 'UTF-8'
sourceCompatibility = 1.8

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

dependencies {
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    compile group: 'org.modelmapper', name: 'modelmapper', version: '1.1.3'
    compile 'com.github.BAData:protobuf-converter:1.1.4'
    compile 'io.grpc:grpc-all:1.11.0'
    compile fileTree(include: ['*.jar'], dir: 'libs')
    compileOnly('org.projectlombok:lombok:1.16.20')
    testCompile group: 'junit', name: 'junit', version: '4.12'
}
sourceSets {
    main {
        java {
            srcDir 'src/main/protoGen'
        }
    }
}

protobuf {
    protoc {
        artifact = 'com.google.protobuf:protoc:3.5.1'
    }
    plugins {
        grpc {
            artifact = "io.grpc:protoc-gen-grpc-java:1.11.0"
        }
    }

    generateProtoTasks {
        ofSourceSet('main').each { task ->
            task.builtins {
                java{
                    outputSubDir = 'protoGen'
                }
            }
            task.plugins {
                grpc {
                    outputSubDir = 'protoGen'
                }
            }
        }
    }
    generatedFilesBaseDir = "$projectDir/src/"
}

task cleanProtoGen{
    doFirst{
        delete("$projectDir/src/main/protoGen")
    }
}
clean.dependsOn cleanProtoGen