#version 330 core
layout (location = 0) out vec4 FragColor;
layout (location = 1) out vec4 BrightColor;

in VS_OUT {
    vec3 FragPos;
    vec3 Normal;
    vec2 TexCoords;
} fs_in;

struct Light {
    vec3 Position;
    vec3 Color;
    float Brightness;
};

uniform Light lights[100]; // 支持最多100个光源
uniform int numLights;     // 当前活动的光源数量
uniform vec3 materialDiffuse;
uniform vec3 materialAmbient;
uniform vec3 materialSpecular;
uniform float materialShininess;
uniform float materialOpacity;
uniform vec3 viewPos;

void main()
{           
    vec3 color = materialDiffuse;
    vec3 normal = normalize(fs_in.Normal);
    // ambient
    vec3 ambient = materialAmbient * color;
    // lighting
    vec3 lighting = vec3(0.0);
    vec3 viewDir = normalize(viewPos - fs_in.FragPos);
    for(int i = 0; i < numLights; i++) // 使用当前活动的光源数量
    {
        // diffuse
        vec3 lightDir = normalize(lights[i].Position - fs_in.FragPos);
        float diff = max(dot(lightDir, normal), 0.0);
        vec3 diffuse = lights[i].Color * diff * color * lights[i].Brightness;
        // specular
        vec3 reflectDir = reflect(-lightDir, normal);
        float spec = pow(max(dot(viewDir, reflectDir), 0.0), materialShininess);
        vec3 specular = lights[i].Color * spec * materialSpecular * lights[i].Brightness;
        // attenuation
        float distance = length(lights[i].Position - fs_in.FragPos);
        float attenuation = 1.0 / (distance * distance);
        lighting += (diffuse + specular) * attenuation;
    }
    vec3 result = ambient + lighting;
    // check whether result is higher than some threshold, if so, output as bloom threshold color
    float brightness = dot(result, vec3(0.2126, 0.7152, 0.0722));
    if(brightness > 1.0)
        BrightColor = vec4(result, 1.0);
    else
        BrightColor = vec4(0.0, 0.0, 0.0, 1.0);
    FragColor = vec4(result, materialOpacity);
}