/**
 * 属性值从local.properites中读取
 * @param name
 * @return
 */
ext.readLocalEnvironment = { String propertyKey ->
    def props = readGradleEnvFromTargetFile("local")
    return props.getProperty(propertyKey)
}

/**
 * 从目标属性文件中读取属性
 * @param fileName 文件名
 * @param name 属性key
 * @return 如果有对应属性, 返回对应属性值; 否则返回null
 */
ext.readGradleEnvFromTargetFile = { String fileName ->
    def props = new Properties()
    props.load(new FileInputStream(rootDir.getAbsolutePath() + "/${fileName}.properties"))
    return props
}

/**
 * 是否本地打包。打包平台打包会自动维护Route文件，不需要手动上传.
 * @return
 */
def isDevelop() {
    def develop = readLocalEnvironment('DEVELOP')
    if (develop == null) {
        develop = "false"
    }
    println "develop -> " + develop
    return develop
}

/**
 * 是否开启严格模式，开启可规范代码的写法和检查代码的执行性能.
 * @return
 */
def isStrictMode() {
    def strictMode = readLocalEnvironment('STRICT_MODE')
    if (strictMode == null) {
        strictMode = "false"
    }
    println "strictMode -> " + strictMode
    return strictMode
}

/**
 * bugly插件debug模式是否开启，开启可自动上传mapping.txt文件，若native项目还可自动上传符号表文件.
 * @return
 */
def isBuglyDebug() {
    def buglyDebug = readLocalEnvironment('BUGLY_DEBUG')
    // 未配置BUGLY_DEBUG开关，区分是本地还是打包平台进行不同的处理
    if (buglyDebug == null) {
        // 服务端打包时加载不到local配置
        File localProFile = rootProject.file("local.properties")
        if (localProFile.exists()) {
            buglyDebug = "false"
        } else {
            // 默认打包平台开启bugly debug模式，本地不允许开启
            buglyDebug = "true"
        }
    }
    println "buglyDebug -> " + buglyDebug
    return buglyDebug
}

ext {
    isDevelop = this.&isDevelop
    isStrictMode = this.&isStrictMode
    isBuglyDebug = this.&isBuglyDebug
}