use "E:\同步空间\EDUCATION\Economics\Econometrics\高级计量经济学课件\高级计量经济学_山大陈强\第二版教材PPT与数据集\第二版教材数据\traffic.dta"  ,clear
xtset state year                                              //定义面板数据结构

xtdes                                                         //显示是面板数据的结构
xtsum fatal spircons beertax unrate perinc                    //显示组内、组件和整体统计指标
xtline fatal spircons beertax unrate perinc                   //显示每个变量的组内时间序列图

global var "spircons beertax unrate perinc"

*------------------OLS估计
*-------混合效应估计
reg fatal spircons beertax unrate perinc 
reg fatal spircons beertax unrate perinc  , r
reg fatal spircons beertax unrate perinc  , cl(state)          //论文中Pooled-Ols标准操作
reg fatal $var ,  cl(state)

*-------固定效应，H0：个体效应与X之间存在显著相关性
*虚拟变量最小二乘法
xi: reg fatal $var          i.state i.year
xi: reg fatal $var reg      i.state i.year                       //不随时间变化的特征，LSDV法可以估计
xi: reg fatal $var i.region i.state i.year                       //字符分类变量需要加上“i.”

*组内均值法
xtreg   fatal $var      i.year ,fe                                //Fe, fixed effect；缺点，仍然需要加i.year 
xtreg   fatal $var      i.year ,fe r                              //异方差稳健标准误
xtreg   fatal $var      i.year ,fe cl(state)                      //在面板数据里面，异方差稳健标准误等同于在自己层面聚类的聚类稳健标准误
xtreg   fatal $var      i.year ,fe cl(reg  )                      //更高维度的聚类稳健标准误

xtreg   fatal $var  reg i.year ,fe                                //不随时间变化的特征，在组内无法估计

*一阶差分法----当变量之间时间序列关系明显
xtserial  fatal $var     , output
xtserial  fatal $var reg , output                                //不随时间变化的特征，一阶差分无法估计

*------随机效应，H0：个体效应与X之间不存在显著相关性
xtreg  fatal $var     i.year ,re                                 //fe 替换成re
xtreg  fatal $var reg i.year ,re                                 //不随时间变化的特征，随机效应可以估计


*豪斯曼检验--检验使用固定效应还是随机效应， Ho: difference in coefficients not systematic
xtreg  fatal $var  i.year ,fe 
estimates store FE
xtreg  fatal $var  i.year , re 
estimates store RE
hausman FE RE, constant sigmamore


*更常用的命令-------提取固定效应(首选)
reghdfe fatal $var  , absorb( state year )                      //高维固定效应
                                                                //优点：1、不需要声明数据的面板类型；
																//      2、可以同时加入多个固定效应
   *多重固定效应
   reghdfe fatal $var  , absorb( state reg year ) 
   reghdfe fatal $var  , absorb( state year breath jaild comserd)                    
   reghdfe fatal $var  , absorb( state year reg breath jaild comserd)                      
														
reghdfe fatal $var  , absorb( id1=state id2=year )               //个体效应的系数代表了随个体变化但不随时间变化的所有变量对Y的平均影响
kdensity id1

*时间交互固定效应
reghdfe fatal $var  , absorb( state i.reg#i.year )               //i.reg#i.year控制了所有随地区且随年份变化的变量对Y的影响

*时间趋势项
reghdfe fatal $var  , absorb( state i.reg#c.year )               //i.reg#c.year控制了随地区变化的时间趋势


*------面板的IV估计【组内均值法、LSDV两者不只是在OLS的估计下等价，在IV的估计下也等价】
ivreghdfe fatal spircons unrate perinc (beertax= mlda), absorb( state year )   //优先使用
reghdfe fatal spircons unrate perinc (beertax= mlda), absorb( state year ) old

xtivreg   fatal spircons unrate perinc (beertax= mlda) i.year ,fe              //先定义面板数据xtset
xi: ivreg fatal spircons unrate perinc (beertax= mlda) i.state i.year