apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

ext {
    configuration = [
            javaVersion = JavaVersion.VERSION_1_7
    ]

    libraries = [
            springBootVersion = "1.5.6.RELEASE",
            springSecurityJwtVersion = "1.0.8.RELEASE",
            jjwtVersion = "0.7.0"
    ]
}

group = 'com.baomidou'
version = '3.7.0'

description = "kisso is a lightweight Java SSO Framework and reusable components."

sourceCompatibility = "${javaVersion}"
targetCompatibility = "${javaVersion}"

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

repositories {
    mavenLocal()
    maven { url 'http://maven.aliyun.com/nexus/content/groups/public/' }
    jcenter()
}

dependencies {
    compileOnly("javax.servlet:servlet-api:2.5")
    compileOnly("javax.servlet:jsp-api:2.0")
    compileOnly("org.springframework.boot:spring-boot-starter-web:${springBootVersion}")
    compileOnly("org.springframework.boot:spring-boot-autoconfigure:${springBootVersion}")

    compile("org.springframework.boot:spring-boot-configuration-processor:${springBootVersion}")
    compile("org.springframework.security:spring-security-jwt:${springSecurityJwtVersion}")
    compile("io.jsonwebtoken:jjwt:${jjwtVersion}")

    testCompile("org.springframework.boot:spring-boot-starter-test:${springBootVersion}")
    testCompile("javax.servlet:servlet-api:2.5")
    testCompile("junit:junit:4.12")
}


task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

javadoc {
    options {
        encoding "UTF-8"
        charSet 'UTF-8'
        author true
        version true
        failOnError false
        links "http://docs.oracle.com/javase/7/docs/api"
    }
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

signing {
    sign configurations.archives
}

// gradle clean build uploadArchives -Dun=用户名 -Dps=密码
uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            def userName = System.getProperty("un")
            def passWord = System.getProperty("ps")
            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: userName, password: passWord)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: userName, password: passWord)
            }

            pom.version = "$project.version"
            pom.artifactId = "$project.name"
            pom.groupId = "$project.group"
            pom.project {
                name 'kisso'
                packaging 'jar'
                description 'kisso is a lightweight Java SSO Framework and reusable components.'
                url 'https://github.com/baomidou/kisso'

                scm {
                    connection 'scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git'
                    developerConnection 'scm:git@github.com:Codearte/gradle-nexus-staging-plugin.git'
                    url 'https://github.com/baomidou/kisso'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'baomidou'
                        name 'hubin'
                        email 'jobob@qq.com'
                    }
                }
            }
        }
    }
}