plugins {
  id "io.spring.dependency-management" version "1.1.0"
  id "com.github.hierynomus.license" version "0.16.1"
  id "org.hidetake.ssh" version "2.11.2"
  id "com.github.johnrengelman.shadow" version "8.1.1"
  id "com.bmuschko.docker-remote-api" version "7.2.0"
  id "com.diffplug.spotless" version "6.18.0"
}

allprojects {

  apply plugin: "java"
  apply plugin: "jacoco"
  apply plugin: "io.spring.dependency-management"
  apply plugin: "com.github.johnrengelman.shadow"
  apply plugin: "com.github.hierynomus.license"
  apply plugin: "com.diffplug.spotless"

  version = "1.0.0-SNAPSHOT"

  ext {
    protobufVersion = "3.19.3"
    grpcVersion = "1.43.2"
    reactorGrpcVersion = "1.2.3"
  }

  java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
  }

  [compileJava, compileTestJava, javadoc]*.options*.encoding = "UTF-8"

  test {
    useJUnitPlatform()
  }

  spotless {
    java {
      removeUnusedImports()
      palantirJavaFormat()
    }
  }

  license {
    ignoreFailures = true
    header = rootProject.file("LICENSE")
    headerURI = com.hierynomus.gradle.license.LicenseBasePlugin.classLoader.getResource("headers/Apache-2.0").toURI()
    skipExistingHeaders = true
    mapping {
      java = "SLASHSTAR_STYLE"
      conf = "SCRIPT_STYLE"
      proto = "DOUBLESLASH_STYLE"
    }
    ext {
      year = "2019-${Calendar.instance.get(Calendar.YEAR)}"
      author = "the original author or authors"
    }
  }

  dependencyManagement {
    imports {
      mavenBom("io.netty:netty-bom:4.1.91.Final")
      mavenBom("org.apache.logging.log4j:log4j-bom:2.20.0")
      mavenBom("io.micrometer:micrometer-bom:1.10.5")
      mavenBom("io.projectreactor:reactor-bom:2022.0.5")
      mavenBom("io.jsonwebtoken:jjwt-root:0.11.5")
      mavenBom("io.grpc:grpc-bom:1.54.0")

      // 单元测试工具
      mavenBom("org.testcontainers:testcontainers-bom:1.18.0")
      mavenBom("org.junit:junit-bom:5.9.2")
      mavenBom("org.mockito:mockito-bom:5.2.0")
    }

    dependencies {
      dependency("org.projectlombok:lombok:1.18.20")
      dependency("com.google.code.findbugs:jsr305:3.0.2")
      dependency("com.typesafe:config:1.4.2")
      dependency("com.github.ben-manes.caffeine:caffeine:3.1.1")
      dependency("io.lettuce:lettuce-core:6.2.3.RELEASE")
      dependency("org.roaringbitmap:RoaringBitmap:0.9.39")
      dependencySet(group: "io.avaje", version: "9.0") {
        entry "avaje-inject-generator"
        entry "avaje-inject"
        entry "avaje-inject-test"
      }
      dependencySet(group: "io.avaje", version: "1.4") {
        entry "avaje-jsonb-generator"
        entry "avaje-jsonb"
        entry "jsonb-jakarta"
      }
      // 单元测试工具
      dependency("net.datafaker:datafaker:1.8.0")
      dependency("org.assertj:assertj-core:3.24.2")
      // 性能测试工具
      dependencySet(group: "org.openjdk.jmh", version: "1.36") {
        entry "jmh-core"
        entry "jmh-generator-annprocess"
      }

      dependency("org.latencyutils:LatencyUtils:2.0.3")
      dependency("io.jsonwebtoken:jjwt-impl:0.11.5")
    }
  }

  dependencies {
    annotationProcessor("org.projectlombok:lombok")
    compileOnly("org.projectlombok:lombok")
    compileOnly("com.google.code.findbugs:jsr305")
    implementation("org.apache.logging.log4j:log4j-core")
    implementation("org.apache.logging.log4j:log4j-slf4j-impl")

    // Test
    testImplementation("org.junit.jupiter:junit-jupiter")
    testImplementation("io.projectreactor:reactor-test")
    testImplementation("io.projectreactor:reactor-tools")
    testImplementation("org.assertj:assertj-core")
    testImplementation("io.avaje:avaje-inject-test")
    testImplementation("net.datafaker:datafaker")
  }

  jar {
    manifest {
      attributes(
        "Created-By": "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})",
        "Implementation-Title": project.name,
        "Implementation-Version": project.version,
        "Built-Date": java.time.OffsetDateTime.now().truncatedTo(java.time.temporal.ChronoUnit.SECONDS)
      )
    }
  }

  repositories {
    maven { url "https://repo.huaweicloud.com/repository/maven/" }
  }
}